Logo Search packages:      
Sourcecode: maradns version File versions

common.inc

define(`TTL', `21600')dnl
dnl
dnl
dnl
dnl
define(`IPCDR', `substr($1, incr(index($1, .)))')dnl
define(`IPCAR', `substr($1, 0, index($1, .))')dnl
define(`IPCADR', `IPCAR(IPCDR($1))')dnl
define(`IPCADDR', `IPCAR(IPCDR(IPCDR($1)))')dnl
define(`IPCADDDR', `IPCDR(IPCDR(IPCDR($1)))')dnl
define(`IPREV', `IPCADDDR($1).IPCADDR($1).IPCADR($1).IPCAR($1).in-addr.arpa')dnl
dnl
dnl
dnl
dnl
dnl ### MaraDNS requires SOA first, followed by all NS records, followed
dnl ### by whatever else.  To remove this requirement from parts files,
dnl ### I used diversions.  SOA is level 0, NS is 10, everything else
dnl ### is 50.
dnl
divert(50)
define(`SERIAL', patsubst(include(`serial'), `
', `'))dnl
define(`SOA', `divert(0)S$1.|TTL|$1.|hostmaster@$1.|SERIAL|7200|3600|604800|1800
divert(50)')dnl
define(`HOST', `A$1.|TTL|$2')dnl
define(`PTR', ``P'IPREV($2).|TTL|$1.')dnl
define(`NS', `divert(10)N$1.|TTL|ns$2.$1.
divert(50)HOST(ns$2.$1, $3)')dnl
define(`MX', `@$1.|TTL|$2|mx$2.$1.
HOST(mx$2.$1, $3)')dnl

Generated by  Doxygen 1.6.0   Back to index